Vbs ( WSH ) ile smtp mail göndermek

Dim emailObj, emailConfig
'Değişkenlerimizi tanımlıyoruz

Set emailObj = CreateObject("CDO.Message")
'Email nesnemizi oluşturuyoruz.

emailObj.From = "ornek@live.com"
'Kimden Örn: ben@live.com

emailObj.To = "sana@live.com"
'Kime Örn: sana@live.com

emailObj.Subject  = "Siparişlerimiz"
'Mesaj konusu/başlığı/title

emailObj.TextBody = "Sayın yetkili 10 adet. Kırmızı kalem siparişimiz vardır."
'Mail/Mesaj içeriğimiz

emailObj.AddAttachment "C:\\OrnekKalem.jpg"
'Mailimize istediğimiz dosyayı ekliyoruz.

Set emailConfig = emailObj.Configuration
'Email nesnemizin ayarları. Bu ayarlar her email servisine göre farklılık gösterir.

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.live.com"
'Mail sağlayıcısının smpt adresi, her sunucunun adresi farklıdır. Veya ayarladan açmak gerekebilir.

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465
'smtp sunucusunun kullandığı port genelde 25 veya 465 olur. Değişkendir.

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
'Bu yöntem hala bu yöntemi kullanan servisler varsa onlar içindir.
'Çoğu modern sunucu artık bu yöntemi kullanmaz.
'1 =cdoSendUsingPickup , 2=cdoSendUsingPort , 3=cdoSendUsingExchange

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
'Bu yöntemde hala authenticate yöntemi kullanan servisler içindir. 1=True için

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
'SSL kullanan servisler için.

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "ornek@live.com"
'Email kullanıcı adınız.

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "****"
'Email şifreniz.

emailConfig.Fields.Update
'Ayarları güncelle

emailObj.Send
'Maili gönder

Set emailobj = Nothing
Set emailConfig = Nothing
'Yarattığımız nesneleri serbest bırakıyoruz.